blob: 0d44eaee5d2edd4ab559eb829039b510d783e135 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: George Hu <integral@archlinux.org>
pkgname=servo-bin
_pkgname="${pkgname%-bin}"
pkgver=0.0.6
pkgrel=1
pkgdesc="A prototype web browser engine written in the Rust language"
arch=('x86_64')
url="https://${_pkgname}.org"
license=('MPL-2.0')
depends=(
'fontconfig'
'gcc-libs'
'glib2'
'glibc'
'gst-plugins-bad-libs'
'gst-plugins-base-libs'
'gstreamer'
'hicolor-icon-theme'
'systemd-libs'
'zlib'
)
provides=("${_pkgname}")
conflicts=("${_pkgname}")
options=("!debug")
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${_pkgname}/${_pkgname}/releases/download/v${pkgver}/${_pkgname}-${CARCH}-linux-gnu.tar.gz")
sha256sums=('bdc554307a869fdefcc4ccc9ee5bbb8bc32dc5c95ef105723487932e7b27b02a')
prepare() {
sed -i '/^Exec=/s|SERVO_SRC_PATH/target/release/||;/TODO:/d' "${_pkgname}/resources/org.servo.Servo.desktop"
}
package() {
cd "${_pkgname}/"
install -Dm755 "${_pkgname}" -t "${pkgdir}/usr/lib/${_pkgname}/"
install -d "${pkgdir}/usr/bin/"
ln -s "/usr/lib/${_pkgname}/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
cp -a resources "${pkgdir}/usr/lib/${_pkgname}/"
cd resources
install -Dm644 "org.servo.Servo.desktop" -t "${pkgdir}/usr/share/applications/"
install -Dm644 "${_pkgname}.svg" -t "${pkgdir}/usr/share/icons/hicolor/scalable/apps/"
install -Dm644 "${_pkgname}_64.png" -t "${pkgdir}/usr/share/icons/hicolor/64x64/apps/"
install -Dm644 "${_pkgname}_1024.png" -t "${pkgdir}/usr/share/icons/hicolor/1024x1024/apps/"
}
|
