From c923ab512290ff77436fbccb19a6a6ebbccc9476 Mon Sep 17 00:00:00 2001
From: moxie <moxie.git@posteo.net>
Date: Mon, 2 Feb 2026 16:57:44 +0000
Subject: init

---
 wlroots-git/PKGBUILD | 76 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 76 insertions(+)
 create mode 100644 wlroots-git/PKGBUILD

(limited to 'wlroots-git/PKGBUILD')

diff --git a/wlroots-git/PKGBUILD b/wlroots-git/PKGBUILD
new file mode 100644
index 0000000..b73b448
--- /dev/null
+++ b/wlroots-git/PKGBUILD
@@ -0,0 +1,76 @@
+pkgname=wlroots-git
+pkgver=0.20.0.r7718.82d5ffb0
+pkgrel=1
+pkgdesc='Modular Wayland compositor library (git development version)'
+arch=(x86_64)
+url=https://gitlab.freedesktop.org/wlroots/wlroots
+license=(MIT)
+depends=(
+	glibc
+	libdrm
+	libinput
+	libliftoff
+	libxcb
+	libglvnd
+	lcms2
+	libxkbcommon
+	systemd-libs
+	opengl-driver
+	pixman
+	wayland
+	xcb-util-errors
+	xcb-util-renderutil
+	xcb-util-wm
+	seatd
+	glslang
+	vulkan-icd-loader
+	libdisplay-info)
+makedepends=(
+	git
+	meson
+	vulkan-headers
+	wayland-protocols
+	xorgproto
+	xorg-xwayland
+)
+optdepends=(
+	'xorg-xwayland: enable X11 support'
+)
+provides=("lib${pkgname%-git}-${pkgver%.*.*.*}.so")
+options=("!debug")
+source=("${pkgname}::git+${url}.git")
+b2sums=('SKIP')
+_builddir="build"
+_builddir_pkgver="build-pkgver"
+
+_meson_setup() {
+	arch-meson \
+		--buildtype=debug \
+		-Dwerror=false \
+		-Dexamples=false \
+		"${pkgname}" "$1"
+}
+
+prepare() {
+	_meson_setup "${_builddir_pkgver}"
+}
+
+pkgver() {
+	(
+		set -o pipefail
+		meson introspect --projectinfo "${_builddir_pkgver}" |
+		awk 'match($0, /"version":\s*"([[:digit:]]+\.[[:digit:]]+\.[[:digit:]]+)-(dev|rc[[:digit:]]+)"/, ret) {printf "%s",ret[1]}'
+	)
+	cd "${pkgname}"
+	printf ".r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+}
+
+build() {
+	_meson_setup "${_builddir}"
+	meson compile -C "${_builddir}"
+}
+
+package() {
+	meson install -C "${_builddir}" --destdir="${pkgdir}"
+	install -Dm644 "${pkgname}/"LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}
-- 
cgit v1.2.3