From c923ab512290ff77436fbccb19a6a6ebbccc9476 Mon Sep 17 00:00:00 2001
From: moxie <moxie.git@posteo.net>
Date: Mon, 2 Feb 2026 16:57:44 +0000
Subject: init

---
 servo-bin/.nvchecker.toml |  4 ++++
 servo-bin/PKGBUILD        | 45 +++++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 49 insertions(+)
 create mode 100644 servo-bin/.nvchecker.toml
 create mode 100644 servo-bin/PKGBUILD

(limited to 'servo-bin')

diff --git a/servo-bin/.nvchecker.toml b/servo-bin/.nvchecker.toml
new file mode 100644
index 0000000..e506bd7
--- /dev/null
+++ b/servo-bin/.nvchecker.toml
@@ -0,0 +1,4 @@
+[servo-bin]
+source = "git"
+git = "https://github.com/servo/servo.git"
+prefix = "v"
diff --git a/servo-bin/PKGBUILD b/servo-bin/PKGBUILD
new file mode 100644
index 0000000..c80148e
--- /dev/null
+++ b/servo-bin/PKGBUILD
@@ -0,0 +1,45 @@
+# Maintainer: George Hu <integral@archlinux.org>
+
+pkgname=servo-bin
+_pkgname="${pkgname%-bin}"
+pkgver=0.0.4
+pkgrel=1
+pkgdesc="A prototype web browser engine written in the Rust language"
+arch=('x86_64')
+url="https://${_pkgname}.org"
+license=('MPL-2.0')
+depends=(
+	'fontconfig'
+	'gcc-libs'
+	'glib2'
+	'glibc'
+	'gst-plugins-bad-libs'
+	'gst-plugins-base-libs'
+	'gstreamer'
+	'hicolor-icon-theme'
+	'systemd-libs'
+	'zlib'
+)
+provides=("${_pkgname}")
+conflicts=("${_pkgname}")
+options=("!debug")
+source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${_pkgname}/${_pkgname}/releases/download/v${pkgver}/${_pkgname}-${CARCH}-linux-gnu.tar.gz")
+sha256sums=('131d99bca0739864098792385c17d789002bc0190325c390fa01d6297f5004a8')
+
+prepare() {
+	sed -i '/^Exec=/s|SERVO_SRC_PATH/target/release/||;/TODO:/d' "${_pkgname}/resources/org.servo.Servo.desktop"
+}
+
+package() {
+	cd "${_pkgname}/"
+	install -Dm755 "${_pkgname}" -t "${pkgdir}/usr/lib/${_pkgname}/"
+	install -d "${pkgdir}/usr/bin/"
+	ln -s "/usr/lib/${_pkgname}/${_pkgname}" "${pkgdir}/usr/bin/${_pkgname}"
+
+	cp -a resources "${pkgdir}/usr/lib/${_pkgname}/"
+	cd resources
+	install -Dm644 "org.servo.Servo.desktop" -t "${pkgdir}/usr/share/applications/"
+	install -Dm644 "${_pkgname}.svg" -t "${pkgdir}/usr/share/icons/hicolor/scalable/apps/"
+	install -Dm644 "${_pkgname}_64.png" -t "${pkgdir}/usr/share/icons/hicolor/64x64/apps/"
+	install -Dm644 "${_pkgname}_1024.png" -t "${pkgdir}/usr/share/icons/hicolor/1024x1024/apps/"
+}
-- 
cgit v1.2.3